StoryMaker™

apply plugin: 'com.android.application'

allprojects {

    repositories {

        jcenter()

        maven { url "https://jitpack.io" }

        flatDir {

            dirs 'libs' //this way we can find the .aar file in libs folder

        }

    }

}

// required for sqlbrite/apt

buildscript {

    repositories {

        maven { url "https://jitpack.io" }

        jcenter()

    }

    dependencies {

        classpath 'com.android.tools.build:gradle:2.0.0'

        classpath 'com.neenbedankt.gradle.plugins:android-apt:1.7'

        classpath 'com.jakewharton.hugo:hugo-plugin:1.2.1'

    }

}

apply plugin: 'com.android.application'

apply plugin: 'com.neenbedankt.android-apt'

apply plugin: 'com.jakewharton.hugo'

android {

    compileSdkVersion 23

    buildToolsVersion "23.0.3"

    sourceSets {

        main {

            manifest.srcFile 'AndroidManifest.xml'

            java.srcDirs = ['src']

            resources.srcDirs = ['src']

            aidl.srcDirs = ['src']

            res.srcDirs = ['res']

            assets.srcDirs = ['assets']

            jniLibs.srcDir file('libs/')

        }

        mainSqlite.setRoot('mainSqlite')

        mainSqlCipher.setRoot('mainSqlCipher')

        beta.setRoot("beta")

        androidTest {

            java.srcDirs = ['tests/src']

            assets.srcDirs = ['tests/assets']

        }

        // If you'd like to provide special files for the debug / release build variants

        // you can do so by adding files to the directories defined below

        //

        // Move the build types to build-types/<type>

        // For instance, build-types/debug/java, build-types/debug/AndroidManifest.xml, ...

        // This moves them out of them default location under src/<type>/... which would

        // conflict with src/ being used by the main source set.

        // Adding new build types or product flavors should be accompanied

        // by a similar customization.

        debug.setRoot('build-types/debug')

        release.setRoot('build-types/release')

    }

    productFlavors {

        mainSqlite {}

        mainSqlCipher {}

    }

    buildTypes {

        beta.initWith(buildTypes.debug)

        beta {}

        debuggableRelease.initWith(buildTypes.release)

        debuggableRelease {

            minifyEnabled false

            debuggable true

        }

    }

    defaultConfig {

        minSdkVersion 16

        targetSdkVersion 22

        multiDexEnabled true

        //testPackageName "org.storymaker.app.tests"

        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"

        //testInstrumentationRunner "com.google.android.apps.common.testing.testrunner.GoogleInstrumentationTestRunner"

    }

    // Temporarily ignore linter errors.

    lintOptions {

        abortOnError false

    }

    packagingOptions {

        exclude 'META-INF/LICENSE.txt'

        exclude 'META-INF/NOTICE.txt'

        exclude 'META-INF/LICENSE'

        exclude 'META-INF/NOTICE'

        exclude 'META-INF/DEPENDENCIES'

        exclude 'LICENSE.txt'

    }

    dexOptions {

        jumboMode = true

        javaMaxHeapSize "2g"

    }

}

// an attempt to fix "Warning:Conflict with dependency 'com.google.code.findbugs:jsr305'. Resolved versions for app (1.3.9) and test app (2.0.1) differ."

// http://stackoverflow.com/questions/19008006/accessing-configurations-resolutionstrategy-from-a-plugin

// this block triggers a "method call is ambiguous error" which seems to be harmless:

// http://stackoverflow.com/questions/25177361/gradle-configurations-all-ambiguous

configurations.all {

    resolutionStrategy.force 'com.google.code.findbugs:jsr305:2.0.1'

}

dependencies {

    compile 'com.android.support:support-v4:23.1.0'

    compile 'com.android.support:support-annotations:23.2.0'

    compile 'com.android.support:recyclerview-v7:23.2.0'

    compile 'com.android.support:cardview-v7:23.1.0'

    compile 'com.google.android.gms:play-services:8.4.0'

    androidTestCompile 'com.android.support.test.espresso:espresso-core:2.0'

    androidTestCompile 'com.android.support.test:testing-support-lib:0.1'

    androidTestCompile 'com.squareup.spoon:spoon-client:1.1.2'

    compile 'com.google.code.gson:gson:2.3'

    compile 'com.google.guava:guava:18.0'

    compile 'net.hockeyapp.android:HockeySDK:3.5.0'

    compile 'commons-io:commons-io:2.4'

    compile 'org.apache.commons:commons-lang3:3.1'

    compile 'info.guardianproject.cacheword:cachewordlib:0.1'

    compile 'net.zetetic:android-database-sqlcipher:3.3.1-1@aar'

    compile 'com.jakewharton.timber:timber:3.1.0'

    compile 'com.edmodo:rangebar:1.0.0'

    //scalio repos via jitpack

    compile 'com.github.n8fr8:NetCipher:n8fr8-dev-release'

    //compile 'com.github.n8fr8:cardsui-for-android:42ed1661c1'

    //compile 'com.github.n8fr8:Android-ViewPagerIndicator:6d15751bca'

    // AAR and  .Jar imports

    compile files('libs/svg-android-1.1.jar')

    compile 'io.scal.secureshare:libsecureshare:0.0.1@aar'

    compile 'com.facebook.android:facebook-release:1.0.0@aar'

    // Project imports

    compile project(':external:android-ffmpeg-java')

    compile project(':external:liger:android-iconify')

    compile project(':external:liger:lib')

}